// alpha.inc  V1.0
//
// An including file for POV-RAY V2.2
// written by MARTIN BORK    1996
// This file includes the ASCII letters from 65 to 90 and 43, 45, 47, 92, 123, 125 as objects.
// ==> A to Z and + - / \ { }
// The y-size of all characters is 10 (12 including the edge).
// The origin is the left bottom (on 65 to 90).
//
// Usage:
//
//   object { Alpha_A
//            scale <...>
//            translate <...>
//            pigment {color rgb<...>}
//            finish {phong ...}
//           }
//
//
// or: object { Alpha_125 .... }
//
#declare Halbring = difference {
                        torus {2.5,1}
                        box {<0,-1.5,-3.5>,<-3.5,1.5,3.5>}
                                }

#declare Hilfsmittel1 = merge {
                         box {<0,-1.5,-3.5>,<-3.5,1.5,3.5>}
                         box {<0,-1.5,0>,<3.5,1.5,3.5>}
                              }

#declare Viertelring = difference {
                        torus {2.5,1}
                        Hilfsmittel1
                                   }

#declare Alpha_B = union {
        sphere {<0,0,0>1}
        cylinder {<0,0,0>,<0,10,0>,1 open}
        sphere {<0,10,0>1}
        cylinder {<0,5,0>,<2.5,5,0>,1 open}
        cylinder {<0,0,0>,<2.5,0,0>,1 open}
        cylinder {<0,10,0>,<2,10,0>,1 open}
        object { Halbring rotate<90,0,0> translate<2.5,2.5,0>}
        object { Halbring rotate<90,0,0> translate<2,7.5,0>}
                         }

#declare Alpha_A = union {
        sphere {<0,0,0>1}
        sphere {<3.75,10,0>1}
        sphere {<7.5,0,0>1}
        cylinder {<0,0,0>,<3.75,10,0>,1 open}
        cylinder {<3.75,10,0>,<7.5,0,0>,1 open}
        cylinder {<1.5,4,0>,<6,4,0>,1 open}
                          }

#declare Alpha_C = union {
        cylinder {<0,2.5,0>,<0,7.5,0>,1 open}
        sphere {<5,7.5,0>1}
        sphere {<5,2.5,0>1}
        object { Halbring rotate<90,0,90> translate<2.5,7.5,0>}
        object { Halbring rotate<90,0,270> translate<2.5,2.5,0>}
                        }

#declare halb_D = difference {
                  object {Alpha_C}
                  box {<2.5,-1,-1>,<-1,11,1>}
                             }

#declare Alpha_D = union {
        cylinder {<5,7.5,0>,<5,2.5,0>,1 open}
        cylinder {<0,0,0>,<2.5,0,0>,1 open}
        cylinder {<0,0,0>,<0,10,0>,1 open}
        cylinder {<0,10,0>,<2.5,10,0>,1 open}
        sphere {<0,10,0>1}
        sphere {<0,0,0>1}
        object {halb_D}
                         }

#declare Alpha_F = union {
        sphere {<0,0,0>1}
        sphere {<0,10,0>1}
        sphere {<5,10,0>1}
        sphere {<4,5,0>1}
        cylinder {<0,0,0>,<0,10,0>,1 open}
        cylinder {<0,10,0>,<5,10,0>,1 open}
        cylinder {<4,5,0>,<0,5,0>,1 open}
                          }

#declare Alpha_E = union {
        object {Alpha_F}
        sphere {<5,0,0>1}
        cylinder {<0,0,0>,<5,0,0>,1 open}
                          }

#declare Alpha_O = union {
        object {Alpha_C}
        cylinder {<5,7.5,0>,<5,2.5,0>,1 open}
                          }

#declare Alpha_Q = union {
        object {Alpha_O}
        sphere {<5.5,0,0>1}
        sphere {<3.5,2.5,0>1}
        cylinder {<5.5,0,0>,<3.5,2.5,0>,1 open}
                          }

#declare Alpha_I = union {
        sphere {<0,0,0>1}
        sphere {<0,10,0>1}
        cylinder {<0,0,0>,<0,10,0>,1 open}
                          }

#declare Alpha_L = union {
        object {Alpha_I}
        cylinder {<0,0,0>,<5,0,0>,1 open}
        sphere {<5,0,0>1}
                          }

#declare Alpha_H = union {
        object {Alpha_I}
        object {Alpha_I translate<5,0,0>}
        cylinder {<0,5,0>,<5,5,0>,1 open}
                          }

#declare Alpha_T = union {
        object {Alpha_I translate<2.5,0,0>}
        sphere {<0,10,0>1}
        sphere {<5,10,0>1}
        cylinder {<0,10,0>,<5,10,0>,1 open}
                          }

#declare Alpha_K = union {
        object {Alpha_I}
        cylinder {<0,3,0>,<5,10,0>,1 open}
        cylinder {<1.25,4.75,0>,<5,0,0>,1 open}
        sphere {<5,0,0>1}
        sphere {<5,10,0>1}
                          }

#declare Alpha_P = union {
        sphere {<0,0,0>1}
        cylinder {<0,0,0>,<0,10,0>,1 open}
        sphere {<0,10,0>1}
        cylinder {<0,5,0>,<2.5,5,0>,1 open}
        cylinder {<0,10,0>,<2,10,0>,1 open}
        object { Halbring rotate<90,0,0> translate<2,7.5,0>}
                         }

#declare Alpha_R = union {
        object {Alpha_P}
        sphere {<5,0,0>1}
        cylinder {<5,0,0>,<2.5,5,0>,1 open}
                          }

#declare Alpha_X = union {
        sphere {<0,0,0>1}
        sphere {<0,10,0>1}
        sphere {<5,10,0>1}
        sphere {<5,0,0>1}
        cylinder {<0,0,0>,<5,10,0>,1 open}
        cylinder {<0,10,0>,<5,0,0>,1 open}
                          }

#declare Alpha_Y = union {
        sphere {<0,0,0>1}
        sphere {<0,10,0>1}
        sphere {<5,10,0>1}
        cylinder {<0,0,0>,<5,10,0>,1 open}
        cylinder {<0,10,0>,<2.5,5,0>,1 open}
                          }

#declare Alpha_N = union {
        object {Alpha_I}
        object {Alpha_I translate<5,0,0>}
        cylinder {<0,10,0>,<5,0,0>,1 open}
                          }

#declare Alpha_M = union {
        object {Alpha_I}
        object {Alpha_I translate<8,0,0>}
        sphere {<4,4,0>1}
        cylinder {<0,10,0>,<4,4,0>,1 open}
        cylinder {<4,4,0>,<8,10,0>,1 open}
                          }

#declare Alpha_J = union {
        object {Halbring rotate<90,0,270> translate<2.5,2.5,0>}
        sphere {<0,2.5,0>1}
        sphere {<5,10,0>1}
        cylinder {<5,2.5,0>,<5,10,0>,1 open}
                          }

#declare Alpha_S = union {
        object {Halbring rotate<90,0,90> translate<2.5,7.5,0>}
        object {Halbring rotate<90,0,270> translate<2.5,2.5,0>}
        sphere {<5,7.5,0>1}
        sphere {<0,2.5,0>1}
        sphere {<0,7.5,0>1}
        sphere {<5,2.5,0>1}
        cylinder {<0,7.5,0>,<5,2.5,0>,1 open}
                          }

#declare Alpha_G = union {
        object {halb_D translate<2,0,0>}
        object {halb_D rotate<0,180,0> translate<5,0,0>}
        cylinder {<2.5,0,0>,<4.5,0,0>,1 open}
        cylinder {<2.5,10,0>,<4.5,10,0>,1 open}
        cylinder {<0,2.5,0>,<0,7.5,0>,1 open}
        cylinder {<3.5,3.5,0>,<7,3.5,0>,1 open}
        cylinder {<7,3.5,0>,<7,2.5,0>,1 open}
        sphere {<7,3.5,0>1}
        sphere {<3.5,3.5,0>1}
                          }

#declare Alpha_U = union {
        object {Halbring rotate<90,0,270> translate<2.5,2.5,0>}
        sphere {<0,10,0>1}
        sphere {<5,10,0>1}
        cylinder {<0,2.5,0>,<0,10,0>,1 open}
        cylinder {<5,2.5,0>,<5,10,0>,1 open}
                          }

#declare Alpha_V = union {
        sphere {<0,10,0>1}
        sphere {<5,10,0>1}
        sphere {<2.5,0,0>1}
        cylinder {<0,10,0>,<2.5,0,0>,1 open}
        cylinder {<5,10,0>,<2.5,0,0>,1 open}
                          }

#declare Alpha_W = union {
        sphere {<0,10,0>1}
        sphere {<2,0,0>1}
        sphere {<3.75,5,0>1}
        sphere {<5.5,0,0>1}
        sphere {<7.5,10,0>1}
        cylinder {<0,10,0>,<2,0,0>,1 open}
        cylinder {<2,0,0>,<3.75,5,0>,1 open}
        cylinder {<3.75,5,0>,<5.5,0,0>,1 open}
        cylinder {<5.5,0,0>,<7.5,10,0>,1 open}
        }

#declare Alpha_Z = union {
        sphere {<0,0,0>1}
        sphere {<7,0,0>1}
        sphere {<1,5,0>1}
        sphere {<6,5,0>1}
        sphere {<7,10,0>1}
        sphere {<0,10,0>1}
        cylinder {<0,10,0>,<7,10,0>,1 open}
        cylinder {<7,10,0>,<0,0,0>,1 open}
        cylinder {<0,0,0>,<7,0,0>,1 open}
        cylinder {<1,5,0>,<6,5,0>,1 open}
                         }

#declare Alpha_43 = union {
       sphere { <0,2.5,0>,1 }
       sphere { <2.5,0,0>,1 }
       sphere { <5,2.5,0>,1 }
       sphere { <2.5,5,0>,1 }
       cylinder {<0,2.5,0>,<5,2.5,0>,1 open}
       cylinder {<2.5,5,0>,<2.5,0,0>,1 open}
                        		  }

#declare Alpha_45 = union{
       sphere { <0,2.5,0>,1 }
       sphere { <5,2.5,0>,1 }
       cylinder {<0,2.5,0>,<5,2.5,0>,1 open}
                           	           }

#declare Alpha_47 = union{
       sphere { <0,0,0>,1 }
       sphere { <5,10,0>,1 }
       cylinder {<0,0,0>,<5,10,0>,1 open}
	                           }

#declare Alpha_92 = union{
       sphere { <0,10,0>,1 }
       sphere { <5,0,0>,1 }
       cylinder {<0,10,0>,<5,0,0>,1 open}
	                           }

#declare Alpha_123 = union{
         object { Viertelring rotate <90,0,90> translate <2.5,7.5,0> }
         object { Viertelring rotate <-90,0,0> translate <-2.5,7.5,0> }
         object { Viertelring rotate <90,0,0> translate <-2.5,2.5,0> }
         object { Viertelring rotate <90,0,180> translate <2.5,2.5,0>}
         object { sphere { <2.5,0,0>,1 } }
         object { sphere { <-2.5,5,0>,1 } }
         object { sphere { <2.5,10,0>,1 } }
                           }

#declare Alpha_125 = union{
         object { Viertelring rotate <-90,0,-90> translate <2.5,7.5,0> }
         object { Viertelring rotate <90,0,0> translate <-2.5,7.5,0> }
         object { Viertelring rotate <-90,0,0> translate <-2.5,2.5,0> }
         object { Viertelring rotate <-90,0,-180> translate <2.5,2.5,0>}
         object { sphere { <-2.5,0,0>,1 } }
         object { sphere { <2.5,5,0>,1 } }
         object { sphere { <-2.5,10,0>,1 } }
                           }